質問

VBAのエラー処理について、良いパターンを教えてください。

特に、このような場合はどうしたらいいのでしょうか。

... some code ...
... some code where an error might occur ...
... some code ...
... some other code where a different error might occur ...
... some other code ...
... some code that must always be run (like a finally block) ...

両方のエラーを処理し、エラーが発生する可能性のあるコードの後で実行を再開したいです。また、最後にあるfinallyのコードは必ず 常に を実行する必要があります - 以前にどんな例外が投げられたかに関係なく。どうすればこの結果を達成できるでしょうか？

どのように解決するのですか？

VBAのエラー処理

• On Error Goto ErrorHandlerLabel
• Resume ( Next | ErrorHandlerLabel )
• On Error Goto 0 (現在のエラーハンドラを無効にする)
• Err オブジェクト

は Err オブジェクトのプロパティは通常、エラー処理ルーチンの中でゼロまたは長さゼロの文字列にリセットされますが、明示的に Err.Clear .

エラー処理ルーチンのエラーは終了しています。

ユーザーエラーの場合、513-65535の範囲が使用可能です。 カスタムクラスのエラーの場合は vbObjectError をエラー番号に追加します。 については、Microsoft のドキュメントを参照してください。 Err.Raise と エラー番号のリスト .

で実装されていないインターフェースのメンバについては 派生した クラスでは、定数 E_NOTIMPL = &H80004001 .

Option Explicit

Sub HandleError()
  Dim a As Integer
  On Error GoTo errMyErrorHandler
    a = 7 / 0
  On Error GoTo 0
  
  Debug.Print "This line won't be executed."
  
DoCleanUp:
  a = 0
Exit Sub
errMyErrorHandler:
  MsgBox Err.Description, _
    vbExclamation + vbOKCancel, _
    "Error: " & CStr(Err.Number)
Resume DoCleanUp
End Sub

Sub RaiseAndHandleError()
  On Error GoTo errMyErrorHandler
    ' The range 513-65535 is available for user errors.
    ' For class errors, you add vbObjectError to the error number.
    Err.Raise vbObjectError + 513, "Module1::Test()", "My custom error."
  On Error GoTo 0
  
  Debug.Print "This line will be executed."

Exit Sub
errMyErrorHandler:
  MsgBox Err.Description, _
    vbExclamation + vbOKCancel, _
    "Error: " & CStr(Err.Number)
  Err.Clear
Resume Next
End Sub

Sub FailInErrorHandler()
  Dim a As Integer
  On Error GoTo errMyErrorHandler
    a = 7 / 0
  On Error GoTo 0
  
  Debug.Print "This line won't be executed."
  
DoCleanUp:
  a = 0
Exit Sub
errMyErrorHandler:
  a = 7 / 0 ' <== Terminating error!
  MsgBox Err.Description, _
    vbExclamation + vbOKCancel, _
    "Error: " & CStr(Err.Number)
Resume DoCleanUp
End Sub

Sub DontDoThis()
  
  ' Any error will go unnoticed!
  On Error Resume Next
  ' Some complex code that fails here.
End Sub

Sub DoThisIfYouMust()
  
  On Error Resume Next
  ' Some code that can fail but you don't care.
  On Error GoTo 0
  
  ' More code here
End Sub