[解決済み] カーソル・ループで使用するために、複数のカラムをフェッチするにはどうすればよいですか？

質問

カーソルループの中で以下のSQLスニペットを実行しようとすると。

set @cmd = N'exec sp_rename ' + @test + N',' +
           RIGHT(@test,LEN(@test)-3) + '_Pct' + N',''COLUMN'''

次のようなメッセージが表示されます。

Msg 15248, Level 11, State 1, Procedure sp_rename, Line 213.

パラメータ @objname があいまいであったり、クレーム @objtype (COLUMN)は間違いです。

何が問題で、どのように修正すればよいのでしょうか？カラム名を括弧で囲んでみました。 [] と二重引用符で囲んでみました。 "" を使用することをお勧めします。

編集1 -

以下はスクリプトの全体です。テーブル名をrename spに渡すにはどうしたらいいですか？カラム名は多くのテーブルのうちの1つにあるので、その方法がよくわかりません。

BEGIN TRANSACTION

declare @cnt int
declare @test nvarchar(128)
declare @cmd nvarchar(500) 
declare Tests cursor for
SELECT COLUMN_NAME FROM INFORMATION_SCHEMA.COLUMNS WHERE COLUMN_NAME LIKE 'pct%' AND TABLE_NAME LIKE 'TestData%'

open Tests
fetch next from Tests into @test
while @@fetch_status = 0
BEGIN
  set @cmd = N'exec sp_rename ' + @test + N',' + RIGHT(@test,LEN(@test)-3) + '_Pct' + N', column' 

  print @cmd

  EXEC sp_executeSQL @cmd

  fetch next from Tests into @test
END

close Tests 
deallocate Tests


ROLLBACK TRANSACTION
--COMMIT TRANSACTION

編集2 このスクリプトは、名前がパターンに一致するカラムの名前を変更するように設計されており、この場合、"pct"という接頭辞が付いています。このカラムは、データベース内のさまざまなテーブルで使用されます。すべてのテーブル名には "TestData"がプレフィックスとして付いています。

どのように解決するのですか？

以下は若干の修正版です。変更点はコードの解説に記載しています。

BEGIN TRANSACTION

declare @cnt int
declare @test nvarchar(128)
-- variable to hold table name
declare @tableName nvarchar(255)
declare @cmd nvarchar(500) 
-- local means the cursor name is private to this code
-- fast_forward enables some speed optimizations
declare Tests cursor local fast_forward for
 SELECT COLUMN_NAME, TABLE_NAME
   FROM INFORMATION_SCHEMA.COLUMNS 
  WHERE COLUMN_NAME LIKE 'pct%' 
    AND TABLE_NAME LIKE 'TestData%'

open Tests
-- Instead of fetching twice, I rather set up no-exit loop
while 1 = 1
BEGIN
  -- And then fetch
  fetch next from Tests into @test, @tableName
  -- And then, if no row is fetched, exit the loop
  if @@fetch_status <> 0
  begin
     break
  end
  -- Quotename is needed if you ever use special characters
  -- in table/column names. Spaces, reserved words etc.
  -- Other changes add apostrophes at right places.
  set @cmd = N'exec sp_rename ''' 
           + quotename(@tableName) 
           + '.' 
           + quotename(@test) 
           + N''',''' 
           + RIGHT(@test,LEN(@test)-3) 
           + '_Pct''' 
           + N', ''column''' 

  print @cmd

  EXEC sp_executeSQL @cmd
END

close Tests 
deallocate Tests

ROLLBACK TRANSACTION
--COMMIT TRANSACTION